UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_StreamFromVar

Définit le texte d'un contrôle à partir d'une variable

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamFromVar ( $hWnd, $sVar )

Paramètres

$hWnd Handle du contrôle
$sVar Une chaîne

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
700 - Tentative de flux avec trop de caractères

Remarques

Si du texte est sélectionné, le contenu de la variable remplace la sélection, sinon remplace tout le texte du contrôle.

Appelez _GUICtrlRichEdit_SetLimitOnText() pour augmenter le nombre de caractères que le contrôle peut contenir.

En relation

_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromFile, _GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar

Voir aussi

Consultez EM_STREAMIN dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit, $s
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Premier paragraphe")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    $s = _GUICtrlRichEdit_StreamToVar($hRichEdit)
                    GUICtrlSetData($idLblMsg, "Sauvé dans variable")
                Case 2
                    _GUICtrlRichEdit_SetText($hRichEdit, "")
                    _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                    GUICtrlSetData($idLblMsg, "Chargé à partir d'une variable")
                Case 3
                    _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                    _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                    GUICtrlSetData($idLblMsg, "Sélection remplacée: un message intentionnel!")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete()   ; est OK aussi
EndFunc   ;==>Example