UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetLimitOnText

Modifie le nombre de caractères pouvant être saisis, collés ou en streaming dans le format Rich Text

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetLimitOnText ( $hWnd, $iNewLimit )

Paramètres

$hWnd Handle du contrôle
$iNewLimit Nouvelle limite

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $iNewLimit n'est ni un nombre positif ni zéro

Remarques

Cette fonction définit la limite du nombre de caractères qu'un utilisateur peut taper ou coller dans un contrôle.

Il limite également le nombre de caractères de texte RTF qui peuvent être générés dans l'utilisation de
_GUICtrlRichEdit_StreamFromFile() et _GUICtrlRichEdit_StreamFromVar().

Il ne limite pas la quantité de texte brut qui peut être généré.

La limite initiale est 32 767 caractères.

En relation

_GUICtrlRichEdit_StreamFromFile, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar

Voir aussi

Consultez EM_EXLIMITTEXT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    Local $idLblMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraphe 1")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 0)
                    GUICtrlSetData($idLblMsg, "1. Limite définie à 65 536 caractères")
                Case 2
                    _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 100000)
                    GUICtrlSetData($idLblMsg, "2. Limite définie à 100 000 caractères")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

     _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
     ; GUIDelete(); est OK aussi
EndFunc   ;==>Example