Fonction _GUICtrlRichEdit

Définit l'ombrage des paragraphe(s) de la sélection courante ou, à défaut de sélection, des paragraphes insérés au point d'insertion

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaShading ( $hWnd [, $iWeight = Default [, $sStyle = Default [, $sForeColor = Default [, $sBackColor = Default]]]] )

Paramètres

Valeur de retour

Remarques

Si du texte est sélectionné, les valeurs par défaut sont les valeurs du premier paragraphe du texte sélectionné.
Si rien n'est sélectionné, les valeurs par défaut sont les valeurs du paragraphe courant.

L'ombrage n'apparaît pas dans RichEdit, mais l'ombrage créé ici sera visible dans Word.

En relation

Voir aussi

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    Report("0. Paragraphe avec les paramètres par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaShading($g_hRichEdit, 60, "ddd", "blu", "dmg")
                    Report("1. Ombrage du second paragraphe is ")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                    Report("2. Le style du premier paragraphe de la sélection est ")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaShading($g_hRichEdit, Default, "dgr")
                    Report("3. Change l'ombrage des deux paragraphes à la fois")
                Case 4
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & @CRLF & _GUICtrlRichEdit_GetParaShading($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report

Succès:	Retourne True.
Échec:	Retourne False et définit @error <> 0.
@error:	101 - $hWnd n'est pas un handle 103 - $sStyle est invalide 104 - $sForeColor est invalide 105 - $sBackColor est invalide 1021 - $iWeight n'est pas un nombre positif 1022 - $iWeight est invalide 700 - l'opération a échoué

$hWnd	Handle du contrôle
$iWeight	[optionnel] Pourcentage de la couleur d'écriture, le reste étant la couleur de fond
$sStyle	[optionnel] Style d'ombrage - une chaîne contenant une des valeurs suivantes : non - aucun dhz - foncé horizontal dvt - foncé vertical ddd - foncé en diagonale vers le bas dud - foncé en diagonale vers le haut dgr - foncé en grille dtr - foncé en treillis lhz - clair horizontal lvt - clair vertical ldd - clair en diagonale vers le bas lud - clair en diagonale vers le haut lgr - clair en grille ltr - clair en treillis
$sForeColor	[optionnel] Une des valeurs suivantes: "blk" - noir (valeur initiale) "blu" - bleu "cyn" - cyan "grn" - vert "mag" - magenta "red" - rouge "yel" - jaune "whi" - blanc "dbl" - bleu foncé "dgn" - vert foncé "dmg" - magenta foncé "drd" - rouge foncé "dyl" - jaune foncé "dgy" - gris foncé "lgy" - gris clair
$sBackColor	[optionnel] Mêmes valeurs que pour $sForeColor