UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetParaShading

Obtient les paramètres d'ombrage du premier paragraphe sélectionné ou, à défaut de sélection, du paragraphe courant

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaShading ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne les paramètres du premier paragraphe sélectionné - une chaîne constituée de valeurs séparées par des points-virgules:
    Valeur 1 - Poids - pour cent de couleur de premier plan, le reste étant la couleur de fond
    Valeur 2 - Style - une chaîne contenant une des valeurs suivantes:
        none - aucun
        dhz - foncé horizontal
        dvt - foncé vertical
        ddd - foncé en diagonale vers le bas
        dud - foncé en diagonale vers le haut
        dgr - foncé en grille
        dtr - foncé en treillis
        lhz - clair horizontal
        lvt - clair vertical
        ldd - clair en diagonale vers le bas
        lud - clair en diagonale vers le haut
        lgr - clair en grille
        ltr - clair en treillis
    Valeur 3 - Couleur de premier plan - une des valeurs suivantes:
        "blk"- noir
        "blu" - bleu
        "cyn"- cyan
        "grn" - vert
        "mag" - magenta
        "red" - rouge
        "yel"- jaune
        "whi"- blanc
        "dbl"- bleu foncé
        "dgn"- vert foncé
        "dmg" - magenta foncé
        "drd"- rouge foncé
        "dyl"- jaune foncé
        "dgy"- gris foncé
        "lgy"- gris clair
    Valeur 4 - Couleur de fond - mêmes valeurs que pour la couleur de premier plan
    Valeur 5 - Portée:
        a - tous (ou seulement) les paragraphes sélectionnés ont ces paramètres
        f - le premier paragraphe sélectionné a ces paramètres, mais d'autres(s) ne l'ont pas
        c - le paragraphe courant a ces paramètres
Échec: Retourne "" et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

Remarque

L'ombrage n'apparaît pas dans RichEdit, mais l'ombrage créé ici sera visible dans Word.

En relation

_GUICtrlRichEdit_SetParaShading

Voir aussi

Consultez EM_SETPARAFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    Report("0. Paragraphe avec les paramètres par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaShading($g_hRichEdit, 60, "ddd", "blu", "dmg")
                    Report("1. Ombrage du second paragraphe is ")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                    Report("2. Le style du premier paragraphe de la sélection est ")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaShading($g_hRichEdit, Default, "dgr")
                    Report("3. Change l'ombrage des deux paragraphes à la fois")
                Case 4
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & @CRLF & _GUICtrlRichEdit_GetParaShading($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report