Fonction _GUICtrlRichEdit_SetParaNumbering

Définit le style de puce des paragraphe(s) de la sélection courante ou, à défaut de sélection, des paragraphe(s) insérés au point d'insertion

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaNumbering ( $hWnd, $sStyle [, $iTextToNbrSpace = Default [, $bForceRoman = False]] )

Paramètres

Valeur de retour

Remarque

En relation

Voir aussi

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 1)
    Report("Paragraphe avec les paramètres de retrait par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, ".")
                    Report("A ajouté un second paragraphe")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                    Report("Style du premier paragraphe de la sélection")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "v)  ", Default, True)
                    Report("Change les paramètres des deux paragraphes")
                Case 4
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "2.  ", Default, True)
                    Report("A changé les paramètres des deux paragraphes")
                Case 5
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction " & @CRLF & _GUICtrlRichEdit_GetParaNumbering($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report

Succès:	Retourne True.
Échec:	Retourne False et définit @error <> 0.
@error:	101 - $hWnd n'est pas un handle 103 - $iTextToNbrSpace n'est pas un nombre postif 104 - $bForceRoman doit être True ou False

$hWnd	Handle du contrôle
$sStyle	Une chaîne spécifiant le style et le numéro de départ: par exemple, "."(bullet), "1)", "(b)", "C.", "iv", "V)" Il s'agit de la puce qui s'affiche dans le premier paragraphe. Les espaces de fuite indiquent les espaces minimaux entre la puce et le paragraphe moins la valeur de $iTextToNbrSpace qui est saisi Cas particuliers: "=" - Ce paragraphe est un paragraphe sans puce dans la liste précédente "" - Retire les puces des paragraphes sélectionnés
$iTextToNbrSpace	[optionnel] Espace entre la puce et le paragraphe (en unités d'espace) Par défaut: nombre d'espaces de fuite fois la taille du point
$bForceRoman	[optionnel] False - i, v, x ... dans $sStyle est la lettre i, v, x ... (par défaut)