UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetParaNumbering

Obtient le style de numérotation du (premier) paragraphe sélectionné ou, à défaut de sélection, du paragraphe courant

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaNumbering ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne des valeurs séparées par des points-virgules:
    Valeur 1 - une chaîne montrant le style et le "numéro" de départ
        par exemple "." (bullet),"1)","(b)","C.","iv","V)"
        Les espaces de fin indiquent les espaces minimaux entre le nombre et le paragraphe
    Cas particuliers:
        "=" - Ce paragraphe est un paragraphe non numéroté dans l'élément de la liste précédente
        "" - La numérotation est enlevée du/des paragraphes sélectionnés
    valeur 2 - Si chiffres romains, "Roman" sinon ""
    valeur 3 - espace entre le nombre/bullet et paragraphe (en unités d'espaces)
    valeur 4 - portée :
        a - tous (ou seulement) les paragraphes sélectionnés ont ces paramètres
        f - le premier paragraphe sélectionné a ces paramètres, mais d'autre(s) ne l'ont pas
        c - le paragraphe courant a ces paramètres
Échec: Retourne "" et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

En relation

_GUICtrlRichEdit_SetParaNumbering

Voir aussi

Consultez EM_GETPARAFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 1)
    Report("Paragraphe avec les paramètres de retrait par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, ".")
                    Report("A ajouté un second paragraphe")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                    Report("Style du premier paragraphe de la sélection")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "v)  ", Default, True)
                    Report("Change les paramètres des deux paragraphes")
                Case 4
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "2.  ", Default, True)
                    Report("A changé les paramètres des deux paragraphes")
                Case 5
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction " & @CRLF & _GUICtrlRichEdit_GetParaNumbering($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report