#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $hRichEdit, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Premier paragraphe")
    _GUICtrlRichEdit_PauseRedraw($hRichEdit)

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetSel($hRichEdit, 5, 2)
                    Report("1.Le dessin du contrôle est en pause")
                Case 2
                    _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTION_2")
                    Report("2.Du texte est inséré au point actif de la sélection")
                Case 3
                    _GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
                    _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTION_3")
                    Report("3.Du texte est inséré au point d'insertion et le dessin du contrôle est activé")
                    _GUICtrlRichEdit_ResumeRedraw($hRichEdit)
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd
 
    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report