UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_InsertText

Insère du texte au point d'insertion ou au point d'ancrage d'une sélection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_InsertText ( $hWnd, $sText )

Paramètres

$hWnd Handle du contrôle
$sText Texte à insérer

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $sText = ""
103 - Ne peut être défini

En relation

_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_GetText, _GUICtrlRichEdit_ReplaceText, _GUICtrlRichEdit_SetText

Voir aussi

Consultez EM_SETTEXTEX dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Premier paragraphe")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetSel($hRichEdit, 5, 2)
                Case 2
                    _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTION_1")
                    GUICtrlSetData($idLblMsg, "Le texte est inséré au point actif de la  sélection")
                Case 3
                    _GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
                    _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTION_2")
                    GUICtrlSetData($idLblMsg, "Le texte est inséré au point d'insertion")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example