UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_ReplaceText

Remplace le texte sélectionné

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ReplaceText ( $hWnd, $sText [, $bCanUndo = True] )

Paramètres

$hWnd Handle du contrôle
$sText Le texte de remplacement
$bCanUndo [optionnel] L'opération peut-elle être annulée? True (par défaut) ou False

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
103 - $bCanUndo doit être True ou False
-1 - Aucun texte n'est sélectionné

En relation

_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_SetText

Voir aussi

Consultez EM_REPLACESEL dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Premier paragraphe")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 5)
                    Case 2
                        _GUICtrlRichEdit_ReplaceText($hRichEdit, "1st")
                        GUICtrlSetData($idLblMsg, "Texte remplacé")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 3)
                        _GUICtrlRichEdit_ReplaceText($hRichEdit, "")
                        GUICtrlSetData($idLblMsg, "1st a été effacé")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example