UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_HideSelection

Cache (ou montre) une sélection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_HideSelection ( $hWnd [, $bHide = True] )

Paramètres

$hWnd Handle du contrôle
$bHide [optionnel]
    True - cache
    False - montre
Par défaut: cache

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $bHide doit être True ou False

Voir aussi

Consultez EM_HIDESELECTION dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 2, 5)
                    Report("Du texte est sélectionné")
                Case 2
                    _GUICtrlRichEdit_HideSelection($g_hRichEdit, True)
                    Report("Sélection cachée")
                Case 3
                    _GUICtrlRichEdit_HideSelection($g_hRichEdit, False)
                    Report("Sélection non cachée")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    Local $sRet = _GUICtrlRichEdit_GetCharAttributes($g_hRichEdit)
    $sMsg = $sMsg & @CRLF & @CRLF & "Attributs caractères=" & $sRet
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report