UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetCharAttributes

Retourne les attributs du texte sélectionné

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharAttributes ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne une chaîne constituée de groupes de trois caractères. Chaque groupe se compose de:
Premier et deuxième caractère: valeurs possibles:
    bo - (bold) caractères gras
    di - (disabled) caractères affichés avec une ombre [nd]
    em - (embossed) en relief [nd]
    hi - (hidded) ne s'affiche pas
    im - (imprinted) imprimé [nd]
    it - (italcized) italique
    li - (EN_LINK) les messages sont envoyés lorsque la souris est sur le texte avec cet attribut
    ou - (outlined) hors ligne [nd]
    pr - (EN_PROTECT) est envoyé lorsque l'utilisateur tente de modifier
    re - (revised) marqué comme révisé [nd]
    sh - (shadowed) ombré [nd]
    sm - (small) petites majuscules [nd]
    st - (struck out) rayé
    sb - (subscript) indice [nd]
    sp - (superscript) exposant [nd]
    un - (underlined) souligné
Troisième caractère : + pour activer, ~ pour mixer
Échec: Retourne "" et définit @error <> 0.
@error: 101 - $hWnd n'est pas une handle
-1 - Aucun texte n'est sélectionné

Remarques

Certains attributs ne s'affichent pas dans un contrôle RichEdit; ils sont marqués par [nd] ci-dessus.

Retourne "" si aucun attribut n'est présent

En relation

_GUICtrlRichEdit_SetCharAttributes

Voir aussi

Consultez EM_GETCHARFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iCp1, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "  Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "http://www.autoitscript.com")
    $iCp1 = _GUICtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
    _GUICtrlRichEdit_SetSel($hRichEdit, $iCp1, $iCp1 + 3)
    Report("Les attributs des Caractères au début de la ligne 2 sont " & _
            _GUICtrlRichEdit_GetCharAttributes($hRichEdit))

    While $iMsg <> GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    GUIDelete()
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report