UDF > GUI > GuiRichEdit >


_GUICtrlRichEdit_GetSelText

Obtient le texte de la sélection courante

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSelText ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne le texte sélectionné.
Échec: Définit @error <> 0.
@error: -1 - Aucun texte n'est sélectionné
101 - $hWnd n'est pas un handle

En relation

_GUICtrlRichEdit_GetSel

Voir aussi

Consultez EM_EXGETSELTEXT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Paragraphe 1")
    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 4)

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    Report("Le texte sélectionné est" & @CRLF & _GUICtrlRichEdit_GetSelText($g_hRichEdit))
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd
    
    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    Local $aRet = _GUICtrlRichEdit_GetSelAA($g_hRichEdit)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & $aRet[0] & "," & $aRet[1]
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report