UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetSel

Obtient les positions inter-caractères basse et haute d'une sélection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSel ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne un tableau au format [<basse>,<haute>].
Échec: Définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

Remarque

Le premier caractère du texte est après la position inter-caractères 0.
Si haute = basse, aucun texte n'est sélectionné.

En relation

_GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_GetSelText, _GUICtrlRichEdit_GetTextInLine, _GUICtrlRichEdit_IsTextSelected, _GUICtrlRichEdit_SetSel

Voir aussi

Consultez EM_EXGETSEL dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetSel($g_hRichEdit, 2, 10)

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    Report("1. Le texte est sélectionné à partir de la position inter-caractère")
                Case 2
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    Report("2. Aucun texte n'est sélectionné maintenant")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    Local $aPos = _GUICtrlRichEdit_GetSel($g_hRichEdit)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & $aPos[0] & "," & $aPos[1]
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report