UDF > GUI > GuiReBar >

_GUICtrlRebar_BeginDrag

Ajoute un nouveau ruban issu d'une opération drag

#include <GuiReBar.au3>
_GUICtrlRebar_BeginDrag ( $hWnd, $iIndex [, $iPos = -1] )

Paramètres

$hWnd Handle du contrôle Rebar
$iIndex Index, de base 0, du ruban que l'opération glisser-déposer affectera
$iPos [optionnel] Valeur DWORD qui contient les coordonnées de départ de la souris.
La coordonnée horizontale est contenue dans le mot de poids faible et la coordonnée verticale est contenue dans le mot de poids fort.
Si vous passez (DWORD)-1, le contrôle Rebar va utiliser la position de la souris obtenue la dernière fois que le thread du contrôle a appelée GetMessage ou PeekMessage

Valeur de retour

Aucune.

En relation

_GUICtrlRebar_DragMove, _GUICtrlRebar_EndDrag

Exemple

#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $idBtnExit, $hReBar, $hToolbar, $idInput, $idBtnBeginDrag, $msg
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Crée un contrôle rebar
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Crée un toolbar pour le placer dans le rebar
    $hToolbar = _GUICtrlToolbar_Create($hGui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Crée un inputbox pour le placer dans le rebar
    $idInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)

    ; Ajoute un ruban avec le contrôle inputbox
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:")

    ; Ajoute un ruban avec le contrôle toolbar au début du rebar
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    $idBtnBeginDrag = GUICtrlCreateButton("Begin Drag", 150, 330, 100, 25)
    $idBtnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    Do
        $msg = GUIGetMsg()
        if $msg = $idBtnBeginDrag Then
            _GUICtrlRebar_BeginDrag($hReBar, 0)
            _GUICtrlRebar_DragMove($hReBar)
            _GUICtrlRebar_EndDrag($hReBar)
        EndIf
    Until $msg =  $GUI_EVENT_CLOSE Or $msg = $idBtnExit
EndFunc   ;==>Example