UDF > GUI > GuiToolbar >

_GUICtrlToolbar_GetBitmapFlags

Obtient les flags qui décrivent le type de bitmap à utiliser

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetBitmapFlags ( $hWnd )

Paramètre

$hWnd Handle du contrôle barre d'outils

Valeur de retour

Retourne une valeur qui décrit le type de bitmap qui doit être utilisé:
    0 - Utilise de petits (16 x 16) bitmaps
    1 - Utilise de grands (24 x 24) bitmaps

Remarque

La valeur retournée n'est que consultative. Le contrôle recommande grands ou de petits bitmaps suivant que l'utilisateur a choisi de grandes ou de petites polices.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example