UDF > GUI > GuiToolbar >

_GUICtrlToolbar_AddButton

Ajoute un bouton

#include <GuiToolbar.au3>
_GUICtrlToolbar_AddButton ( $hWnd, $iID, $iImage [, $iString = 0 [, $iStyle = 0 [, $iState = 4 [, $iParam = 0]]]] )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iID ID de la commande relative au bouton à ajouter
$iImage Index, de base 0, de l'image du bouton.
Définissez ce paramètre à -1 et le contrôle transmettra la notification $TBN_GETDISPINFO pour récupérer l'index d'image quand c'est nécessaire.
Définissez-le à -2 pour indiquer que le bouton n'a pas d'image.
La disposition des boutons ne comprendra que l'espace pour le texte.
Si le bouton est un séparateur, il s'agit de la largeur du séparateur, en pixels.
$iString [optionnel] Index, de base 0, de la chaîne de bouton qui a été créé avec AddString
$iStyle [optionnel] Style de bouton. Peut être une combinaison des éléments suivants:
    $BTNS_AUTOSIZE - Le contrôle barre d'outils ne doit pas affecter la largeur standard du bouton
    $BTNS_BUTTON - Bouton standard (par défaut)
    $BTNS_CHECK - Bouton qui bascule entre les états pressé et non pressé
    $BTNS_CHECKGROUP - Bouton qui reste enfoncé jusqu'à ce qu'un autre bouton dans le groupe soit pressé
    $BTNS_DROPDOWN - Crée un bouton de style déroulant qui permet d'afficher une liste
    $BTNS_GROUP - Bouton qui reste enfoncé jusqu'à ce qu'un autre bouton dans le groupe soit pressé
    $BTNS_NOPREFIX - Le texte du bouton n'aura pas un préfixe d'accélérateur
    $BTNS_SEP - Crée un séparateur
    $BTNS_SHOWTEXT - Indique que le texte du bouton doit être affiché
    $BTNS_WHOLEDROPDOWN - Indique que le bouton aura une flèche déroulante
$iState [optionnel] État du bouton. Peut être une combinaison des éléments suivants:
    $TBSTATE_CHECKED - Le bouton a le style $TBSTYLE_CHECK et est en train d'être cliqué
    $TBSTATE_PRESSED - Le bouton est cliqué
    $TBSTATE_ENABLED - Le bouton accepte l'entrée utilisateur
    $TBSTATE_HIDDEN - Le bouton n'est pas visible et ne peut pas recevoir une entrée utilisateur
    $TBSTATE_INDETERMINATE - Le bouton est grisé
    $TBSTATE_WRAP - Le bouton est suivie par une coupure de ligne
    $TBSTATE_ELLIPSES - Le texte du bouton est coupé et une ellipse est affichée
    $TBSTATE_MARKED - Le bouton est marqué
$iParam [optionnel] Valeur définie par l'application

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlToolbar_DeleteButton, _GUICtrlToolbar_InsertButton

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Add standard system bitmaps
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Add buttons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example