UDF > GUI > GuiReBar >

_GUICtrlRebar_AddBand

Ajoute un nouveau ruban dans un contrôle Rebar

#include <GuiReBar.au3>
_GUICtrlRebar_AddBand ( $hWndRebar, $hWndChild [, $iMinWidth = 100 [, $iDefaultWidth = 100 [, $sText = "" [, $iIndex = -1 [, $iStyle = -1]]]]] )

Paramètres

$hWndRebar Handle du contrôle Rebar
$hWndChild Handle du contrôle à ajouter
$iMinWidth [optionnel] Largeur minimale du ruban
$iDefaultWidth [optionnel] Longueur du ruban, en pixels
$sText [optionnel] Texte d'affichage pour le ruban
$iIndex [optionnel] Indice, de base 0, de l'endroit où le ruban sera inséré.
Si vous définissez ce paramètre à -1, le contrôle ajoute le nouveau ruban en dernière position
$iStyle [optionnel] Flags qui spécifient le style du ruban. Cette valeur peut être une combinaison des valeurs suivants:
    $RBBS_BREAK - Le ruban est sur une nouvelle ligne.
    $RBBS_CHILDEDGE - Le ruban a un bord en haut et en bas de la fenêtre enfant.
    $RBBS_FIXEDBMP - L'image bitmap d'arrière-plan ne bouge pas lorsque la bande est redimensionnée.
    $RBBS_FIXEDSIZE - Le ruban ne peut pas être redimensionné. Avec ce style, la poignée de redimensionnement n'est pas affiché sur la bande.
    $RBBS_GRIPPERALWAYS - Version 4.71. Le ruban aura toujours une poignée de redimensionnement, même s'il est le seul ruban de la barre Rebar.
    $RBBS_HIDDEN - Le ruban ne sera pas visible.
    $RBBS_NOGRIPPER - Version 4.71. Le ruban n'aura jamais une poignée de redimensionnement, même s'il y a plusieurs un ruban dans la Rebar.
    $RBBS_USECHEVRON - Version 5.80. Affiche un bouton chevron si le ruban est plus petit que cxIdeal.
    $RBBS_VARIABLEHEIGHT - Version 4.71. Le ruban peut être redimensionné par le contrôle Rebar; cyIntegral et cyMaxChild affectent la façon dont le Rebar va redimensionner le ruban.
    $RBBS_NOVERT - N'affiche pas en position verticale.
    $RBBS_USECHEVRON - Affiche un bouton déroulant.
    $RBBS_HIDETITLE - Garde le titre du ruban caché.
    $RBBS_TOPALIGN - Garde le ruban dans la rangée du haut.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlRebar_AddToolBarBand, _GUICtrlRebar_DeleteBand

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <GuiReBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $idBtnExit, $hCombo, $hReBar, $hDTP, $idInput, $msg

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Crée un contrôle rebar
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Crée un combobox pour le placer dans le rebar
    $hCombo = _GUICtrlComboBox_Create($hGui, "", 0, 0, 120)

    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Crée un date time picker pour le placer dans le rebar
    $hDTP = _GUICtrlDTP_Create($hGui, 0, 0, 190)

    ; Crée un inputbox pour le placer dans le rebar
    $idInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)

    ; Ajoute un ruban au contrôle
    _GUICtrlRebar_AddBand($hReBar, $hCombo, 120, 200, "Dir *.exe")

    ; Ajoute et force la position sur la deuxième rangée
    _GUICtrlRebar_AddBand($hReBar, $hDTP, 120)
    _GUICtrlRebar_SetBandStyleBreak($hReBar, 1)

    ; Ajoute et force la position au début de la rebar
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:", 0)

    $idBtnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE Or $msg = $idBtnExit
EndFunc   ;==>Example