UDF > GUI > GuiListView >

_GUICtrlListView_SetWorkAreas

Crée une zone de travail dans le contrôle

#include <GuiListView.au3>
_GUICtrlListView_SetWorkAreas ( $hWnd, $iLeft, $iTop, $iRight, $iBottom )

Paramètres

$hWnd ID/handle du contrôle
$iLeft Coordonnée X du coin supérieur gauche du rectangle,
$iTop La coordonnée Y du coin supérieur gauche du rectangle,
$iRight Coordonnée X du coin inférieur droit du rectangle
$iBottom Coordonnée Y du coin inférieur droit du rectangle

Valeur de retour

Aucune.

En relation

_GUICtrlListView_GetNumberOfWorkAreas

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hImage, $idListview

    GUICreate("ListView Set Work Areas", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($idListview, $LVS_ICON)
    GUISetState(@SW_SHOW)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 0)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, 0, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
    _GUICtrlListView_AddItem($idListview, "Item 2", 1)
    _GUICtrlListView_AddItem($idListview, "Item 3", 2)

    ; Crée une zone de travail
    _GUICtrlListView_SetWorkAreas($idListview, 0, 0, 100, 100)
    MsgBox($MB_SYSTEMMODAL, "Information", "Work Areas: " & _GUICtrlListView_GetNumberOfWorkAreas($idListview))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example