UDF > GUI > GuiListView >

_GUICtrlListView_GetImageList

Obtient le handle de la liste d'image utilisée pour dessiner les éléments d'une ListView

#include <GuiListView.au3>
_GUICtrlListView_GetImageList ( $hWnd, $iImageList )

Paramètres

$hWnd ID/handle du contrôle
$iImageList Liste d'images à récupérer:
0 - Liste d'images avec de grandes icônes
1 - Liste d'images avec de petites icônes
2 - Liste d'images avec des images d'état

Valeur de retour

Succès: Retourne le handle de la liste d'image spécifié.
Échec: Retourne 0.

En relation

_GUICtrlListView_SetImageList

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hImage, $idListview

    GUICreate("ListView Get Image List", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Charge des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
    _GUICtrlListView_AddItem($idListview, "Item 2", 1)
    _GUICtrlListView_AddItem($idListview, "Item 3", 2)

    ; Obtient le handle de la liste d'images
    MsgBox($MB_SYSTEMMODAL, "Information", "Image List Handle: 0x" & Hex(_GUICtrlListView_GetImageList($idListview, 1)) & @CRLF & _
            "IsPtr = " & IsPtr(_GUICtrlListView_GetImageList($idListview, 1)) & " IsHWnd = " & IsHWnd(_GUICtrlListView_GetImageList($idListview, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example