UDF > GUI > GuiListView >

_GUICtrlListView_GetCallbackMask

Obtient le masque de rappel du contrôle

#include <GuiListView.au3>
_GUICtrlListView_GetCallbackMask ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Retourne la valeur du masque de rappel. Les bits du masque indiquent les états des éléments ou des images pour lesquels l'application stocke les données de l'état actuel. Cette valeur peut être une combinaison quelconque des valeurs suivantes:
    1 - L'élément est marqué pour une opération couper-coller
    2 - L'élément est surligné comme une cible d'un glisser-déposer
    4 - L'élément a le focus
    8 - L'élément est sélectionné
    16 - L'application stocke l'index, dans la liste d'image, de l'image de superposition courante
    32 - L'application stocke l'index, dans la liste d'image, de l'image de l'état actuel

Remarques

Le masque de rappel est un ensemble de bits qui définissent les états des éléments pour lesquels l'application, plutôt que le contrôle, stocke les données actuelles.
Le masque de rappel s'applique à tous les éléments du contrôle, contrairement à la désignation de l'élément de rappel, qui s'applique à un élément spécifique.
Le masque de rappel est zéro par défaut, ce qui signifie que le contrôle stocke toutes les informations d'état des éléments.

En relation

_GUICtrlListView_SetCallBackMask

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example_UDF_Created()

Func Example_UDF_Created()
    Local $hGUI, $hImage, $hListView

    $hGUI = GUICreate("(UDF Created) ListView Get CallBack Mask", 400, 300)

    $hListView = _GUICtrlListView_Create($hGUI, "", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    _GUICtrlListView_SetCallBackMask($hListView, 32)
    MsgBox($MB_SYSTEMMODAL, "Information", "CallBackMask: " & _GUICtrlListView_GetCallbackMask($hListView))

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xC0C0C0, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF00FF, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFFFF00, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)
    _GUICtrlListView_SetImageList($hListView, $hImage, 2)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; Ajoute des éléments with callback for item text
    _GUICtrlListView_AddItem($hListView, -1, 0)
    _GUICtrlListView_AddItem($hListView, -1, 1)
    _GUICtrlListView_AddItem($hListView, -1, 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example_UDF_Created