UDF > GUI > GuiListView >


_GUICtrlListView_GetBkImage

Obtient l'image d'arrière-plan du contrôle

#include <GuiListView.au3>
_GUICtrlListView_GetBkImage ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Un ou plusieurs des options suivantes:
        0 - Le contrôle n'a pas d'arrière-plan
        1 - L'arrière-plan est un bitmap
        2 - L'arrière-plan est une URL
    [1] - URL de l'image d'arrière-plan
    [2] - Pourcentage de la zone cliente représentant le décalage horizontal de l'image
    [3] - Pourcentage de la zone cliente représentant le décalage vertical de l'image

En relation

_GUICtrlListView_SetBkImage

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example_UDF_Created() ; use UDF built listview

Func Example_UDF_Created()
    Local $hGUI, $hImage, $aImage, $hListView
    Local $iStylesEx = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER)

    $hGUI = GUICreate("(UDF Created) ListView Set Background Image", 600, 550)

    $hListView = _GUICtrlListView_Create($hGUI, "", 2, 2, 596, 500, -1, -1, True) ; Last option Calls CoInitializeEx
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $iStylesEx)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
    _GUICtrlListView_InsertColumn($hListView, 1, "Column 2", 100)
    _GUICtrlListView_InsertColumn($hListView, 2, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

    ; Construit des groupes
    _GUICtrlListView_EnableGroupView($hListView)
    _GUICtrlListView_InsertGroup($hListView, -1, 1, "Group 1")
    _GUICtrlListView_InsertGroup($hListView, -1, 2, "Group 2")
    _GUICtrlListView_SetItemGroupID($hListView, 0, 1)
    _GUICtrlListView_SetItemGroupID($hListView, 1, 2)
    _GUICtrlListView_SetItemGroupID($hListView, 2, 2)

    ; Obtient une Image
    Local $sURL = "http://www.autoitscript.com/autoit3/files/graphics/autoit9_wall_grey_800x600.jpg"
    Local $sFilePath = @ScriptDir & "\AutoIt.jpg"
    InetGet($sURL, $sFilePath)

    ; Définit l'image d'arrière-plan
    _GUICtrlListView_SetBkImage($hListView, $sFilePath)
    $aImage = _GUICtrlListView_GetBkImage($hListView)

    GUISetState(@SW_SHOW)

    MsgBox($MB_SYSTEMMODAL, "Information", "Background Image: " & $aImage[1])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Doit être appelée pour chaque appel de CoInitializeEx
    DllCall('ole32.dll', 'long', 'CoUinitialize')
    GUIDelete()
    FileDelete($sFilePath)
EndFunc   ;==>Example_UDF_Created