#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Global $g_idListView

Example()

Func Example()
    Local $hImage, $iTime

    GUICreate("ListView Cancel Edit", 392, 322)
    $g_idListView = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_EDITLABELS, $LVS_REPORT))
    GUISetState(@SW_SHOW)

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    ; Charge des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($g_idListView), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($g_idListView), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($g_idListView), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($g_idListView, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_InsertColumn($g_idListView, 0, "Column 1", 100)
    _GUICtrlListView_InsertColumn($g_idListView, 1, "Column 2", 100)
    _GUICtrlListView_InsertColumn($g_idListView, 2, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($g_idListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($g_idListView, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($g_idListView, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($g_idListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($g_idListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($g_idListView, "Row 3: Col 1", 2)

    ; Edite l'étiquette de l'élément 0 avec délai limite
    _GUICtrlListView_EditLabel($g_idListView, 0)
    $iTime = TimerInit()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
        If _GUICtrlListView_GetEditControl($g_idListView) <> 0 Then
            If TimerDiff($iTime) > 3000 Then _GUICtrlListView_CancelEditLabel($g_idListView)
        EndIf
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $g_idListView
    If Not IsHWnd($g_idListView) Then $hWndListView = GUICtrlGetHandle($g_idListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    If $hWndFrom = $hWndListView Then
        Switch $iCode
            Case $LVN_COLUMNCLICK 
                ; Une colonne a été cliquée
                $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                _DebugPrint("$LVN_COLUMNCLICK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode & @CRLF & _
                        "-->Item:" & @TAB & DllStructGetData($tInfo, "Item") & @CRLF & _
                        "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                        "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                        "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                        "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                        "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                        "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                        "-->Param:" & @TAB & DllStructGetData($tInfo, "Param"))
                ; Aucune valeur retournée

            Case $LVN_ITEMCHANGING 
                ; Un élément est en cours de modification
                $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                _DebugPrint("$LVN_ITEMCHANGING" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode & @CRLF & _
                        "-->Item:" & @TAB & DllStructGetData($tInfo, "Item") & @CRLF & _
                        "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                        "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                        "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                        "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                        "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                        "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                        "-->Param:" & @TAB & DllStructGetData($tInfo, "Param"))
                Return True ; Empêche les modifications
                ; Return False ; Autorise les modifications

            Case $LVN_KEYDOWN 
                ; Une touche a été pressée
                $tInfo = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                _DebugPrint("$LVN_KEYDOWN" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode & @CRLF & _
                        "-->VKey:" & @TAB & DllStructGetData($tInfo, "VKey") & @CRLF & _
                        "-->Flags:" & @TAB & DllStructGetData($tInfo, "Flags"))
                ; Aucune valeur a été retournée

            Case $NM_CLICK 
                ; Envoyé par un contrôle ListView quand l'utilisateur clique sur un élément avec le bouton gauche de la souris
                $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                _DebugPrint("$NM_CLICK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode & @CRLF & _
                        "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                        "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                        "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                        "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                        "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                        "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                        "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                        "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                        "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                ; Aucune valeur retournée

            Case $NM_DBLCLK 
                ; Envoyé par un contrôle ListView quand l'utilisateur double-clique sur un élément avec le bouton gauche de la souris
                $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                _DebugPrint("$NM_DBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode & @CRLF & _
                        "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                        "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                        "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                        "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                        "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                        "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                        "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                        "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                        "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                ; Aucune valeur retournée

            Case $NM_KILLFOCUS 
                ; Le contrôle a perdu le focus d'entrée
                _DebugPrint("$NM_KILLFOCUS" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode)
                ; Aucune valeur retournée

            Case $NM_RCLICK 
                ; Envoyé par un contrôle ListView quand l'utilisateur clique sur un élément avec le bouton droit de la souris
                $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                _DebugPrint("$NM_RCLICK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode & @CRLF & _
                        "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                        "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                        "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                        "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                        "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                        "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                        "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                        "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                        "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                ; Return 1 ; ne pas autoriser le traitement par défaut
                Return 0 ; autoriser le traitement par défaut

            Case $NM_RDBLCLK 
                ; Envoyé par un contrôle ListView quand l'utilisateur double-clique sur un élément avec le bouton droit de la souris
                $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                _DebugPrint("$NM_RDBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode & @CRLF & _
                        "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                        "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                        "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                        "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                        "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                        "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                        "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                        "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                        "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                ; Aucune valeur retournée

            Case $NM_RETURN 
                ; Le contrôle a le focus d'entrée et l'utilisateur a pressé la touche ENTER
                _DebugPrint("$NM_RETURN" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode)
                ; Aucune valeur retournée

            Case $NM_SETFOCUS 
                ; Le contrôle a reçu le focus d'entrée
                _DebugPrint("$NM_SETFOCUS" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                        "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                        "-->Code:" & @TAB & $iCode)
                ; Aucune valeur retournée
        EndSwitch
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_Text, $sLine = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @CRLF & _
            "+======================================================" & @CRLF & _
            "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text & @CRLF & _
            "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint