UDF > GUI > GuiEdit >


_GUICtrlEdit_GetTextLen

Obtient la longueur du texte complet du contrôle d'édition

#include <GuiEdit.au3>
_GUICtrlEdit_GetTextLen ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne la longueur du texte du contrôle d'édition.

En relation

_GUICtrlEdit_GetText

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[2] = [378, -1]

    ; Crée une GUI
    $hGUI = GUICreate("Edit Get Text Len", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 1, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Définit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Définit le texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))

    ; Get Text Len
    _GUICtrlStatusBar_SetText($hStatusBar, "Text Len: " & _GUICtrlEdit_GetTextLen($idEdit) & " chars")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example