UDF > GUI > GuiToolTip >

_GUIToolTip_SetTipBkColor

Définit la couleur de fond d'une info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_SetTipBkColor ( $hWnd, $iColor )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$iColor Nouvelle couleur de fond (voir Remarques)

Valeur de retour

Aucune.

Remarque

La valeur de la couleur utilisée dans la fonction _GUIToolTip_SetTipBkColor() est une valeur COLORREF (BGR) dans le format 0x00bbggrr. L'octet de poids faible contient une valeur pour l'intensité relative de rouge, le second octet contient une valeur pour le vert et le troisième octet contient une valeur pour le bleu.
L'octet de poids fort doit être zéro.

En relation

_GUIToolTip_GetTipBkColor, _GUIToolTip_SetTipTextColor

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <WinAPITheme.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("Button ToolTip", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle
    Local $hToolTip = _GUIToolTip_Create($hGUI, BitOR($TTS_BALLOON, $_TT_ghTTDefaultStyle))
    ; Si vous utilisez un paramètre de thème Windows, il est désactivé pour que l'info-bulle
    ; soit affichée, ainsi vous pouvez modifier les marges et voir le changement    
    _WinAPI_SetWindowTheme($hToolTip, "", "")

    ; La valeur de la couleur utilisée dans la fonction _GUIToolTip_SetTipBkColor est une valeur  COLORREF (BGR).
    _GUIToolTip_SetTipBkColor($hToolTip, 0x395A00)
    ; La valeur de la couleur utilisée dans la fonction _GUIToolTip_SetTipBkColor est une valeur  COLORREF (BGR).
    _GUIToolTip_SetTipTextColor($hToolTip, 0x1EBFFF)

    ; Ajoute un élément au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is the ToolTip text", $hButton)
    GUISetState(@SW_SHOW)
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    
    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example