UDF > GUI > GuiToolTip >

_GUIToolTip_EnumTools

Extrait des informations sur un élément déclencheur d'un contrôle info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_EnumTools ( $hWnd, $iIndex )

Paramètres

$hWnd Handle du contrôle info-bulle (retourné par _GUIToolTip_Create.)
$iIndex Index, de base 0, de l'élément déclencheur pour lequel il faut récupérer des informations

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Chaîne avec séparateur virgule affichant les flags TTF_* utilisés
        TTF_IDISHWND = Indique que $iID est le handle de la fenêtre de l'élément à la place de l'ID
        TTF_CENTERTIP = Centre la fenêtre au dessous del'élément spécifié par $iID
        TTF_RTLREADING = Indique que le texte sera affiché dans la direction opposée
        TTF_SUBCLASS = Indique que le contrôle doit prendre le dessus sur la fenêtre de l'élément déclencheur pour intercepter les messages
        TTF_TRACK = Positionne le contrôle proche de l'élément déclencheur
        TTF_ABSOLUTE = Positionne la fenêtre aux mêmes coordonnées fournies par TTM_TRACKPOSITION
        TTF_TRANSPARENT = Force le contrôle à transmettre les messages de la souris à la fenêtre parent
        TTF_PARSELINKS = Indique que les liens dans le texte du contrôle doivent être affichés en tant que liens
    [1] - Handle de la fenêtre qui contient l'élément déclencheur($hWnd)
    [2] - Identifiant de l'élément ($iID)
    [3] - Coordonnée X du coin supérieur gauche du rectangle
    [4] - Coordonnée Y du coin supérieur gauche du rectangle
    [5] - Coordonnée X du coin inférieur droit du rectangle
    [6] - Coordonnée Y du coin inférieur droit du rectangle
    [7] - Handle de l'instance qui contient la ressource chaîne pour l'élément
    [8] - Texte de l'élément
    [9] - Valeur définie par l'application associée à l'élément

En relation

_GUIToolTip_GetCurrentTool, _GUIToolTip_GetToolInfo

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Crée un contrôle info-bulle avec les paramètres par défaut
    Local $hToolTip = _GUIToolTip_Create(0)

    ; Ajoute un élément déclencheur au contrôle info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is a ToolTip", $hButton)
    _GUIToolTip_AddTool($hToolTip, 0, "This is the GUI ToolTip", $hGUI)
    GUISetState(@SW_SHOW)
    ; GetToolCount retourne 2, mais les éléments sont numérotés à partir de 0, donc nous avons soustrait 1
    For $I = 0 To _GUIToolTip_GetToolCount($hToolTip) - 1
        Local $aTool = _GUIToolTip_EnumTools($hToolTip, $I)
        MsgBox($MB_SYSTEMMODAL, "Tooltip info for tooltip - " & $I, "Flags: " & @TAB & _GUIToolTip_BitsToTTF($aTool[0]) & @CRLF & _
                "HWnd: " & @TAB & $aTool[1] & @CRLF & _
                "ID: " & @TAB & $aTool[2] & @CRLF & _
                "Left X:" & @TAB & $aTool[3] & @CRLF & _
                "Left Y:" & @TAB & $aTool[4] & @CRLF & _
                "Right X:" & @TAB & $aTool[5] & @CRLF & _
                "Right Y:" & @TAB & $aTool[6] & @CRLF & _
                "Instance:" & @TAB & $aTool[7] & @CRLF & _
                "Text:" & @TAB & $aTool[8] & @CRLF & _
                "lParam:" & @TAB & $aTool[9])
    Next

    ; Détruit le contrôle info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example