UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetZoom

Détermine le niveau de zoom du contrôle

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetZoom ( $hWnd, $iPercent )

Paramètres

$hWnd Handle du contrôle
$iPercent Pourcentage de zoom
Valeurs : 100 et de 200 à 6400

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
1021 - $iPercent n'est pas un nombre positif
1022 - $iPercent n'est ni 100 ni dans la plage de 200 à 6400

Remarque

MSDN affirme que EM_SETZOOM fonctionne de 1,56% (1/64) à 6400% (64/1), mais les tests montrent qu'elle ne fonctionne de manière fiable que pour les valeurs indiquées ci-dessus.

En relation

_GUICtrlRichEdit_GetZoom

Voir aussi

Consultez EM_SETZOOM dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $hRichEdit, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Ceci est du texte ajouté.")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    Report("1.A zoomé maintenant à " & _GUICtrlRichEdit_GetZoom($hRichEdit) & "%")
                Case 2
                    _GUICtrlRichEdit_SetZoom($hRichEdit, 250)
                    Report("2.A zoomé maintenant à " & _GUICtrlRichEdit_GetZoom($hRichEdit) & "%")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd
 
    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report