UDF > GUI > GuiRichEdit >


_GUICtrlRichEdit_SetUndoLimit

Définit le nombre maximum d'actions qui peut être stockées dans la file d'attente d'annulation

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetUndoLimit ( $hWnd, $iLimit )

Paramètres

$hWnd Handle du contrôle
$iLimit Le nombre maximum d'actions pouvant être stockées dans la file d'attente d'annulation

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $iLimit n'est ni un nombre positif ni zéro

Remarques

Pour désactiver la fonctionnalité d'annulation, mettez $iLimit à zéro.

La valeur initiale de $iLimit est de 100.

En relation

_GUICtrlRichEdit_CanRedo, _GUICtrlRichEdit_CanUndo, _GUICtrlRichEdit_GetNextRedo, _GUICtrlRichEdit_Redo, _GUICtrlRichEdit_Undo

Voir aussi

Consultez EM_SETUNDOLIMIT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Premier paragraphe")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetUndoLimit($hRichEdit, 200)
                    GUICtrlSetData($idLblMsg, "A incrémenté le nombre d'actions qui peut être stockées dans la file d'attente d'annulation de 100 à 200")
                Case 2
                    _GUICtrlRichEdit_SetUndoLimit($hRichEdit, 0)
                    GUICtrlSetData($idLblMsg, "L'annulation d'actions est désactivée")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example