UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetTabStops

Définit des taquets de tabulation pour le contrôle

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetTabStops ( $hWnd, $vTabStops [, $bRedraw = True] )

Paramètres

$hWnd Handle du contrôle
$vTabStops Taquet(s) de tabulation à définir en unités d'espacement:
Si une chaîne, les positions des taquets de tabulation sont séparés par des points-virgules
Si numérique, définit un taquet de tabulation à chaque -n- unités d'espacement
$bRedraw [optionnel] Pour redessiner le contrôle - True (par défaut) ou False

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
103 - $bRedraw doit être True ou False
1021 - $vTabStops n'est ni une chaîne ni un nombre
1022 - $vTabStops est une chaîne mais un taquet de tabulation dans cette chaîne n'est pas un nombre positif
1023 - $vTabStops est une chaîne vide
1024 - $vTabStops est un nombre, mais il est nul ou négative

Remarque

Les unités d'espacement sont initialement en pouces.
Pour saisir un taquet dans un contrôle, appuyez sur Ctrl_Tab.

En relation

_GUICtrlRichEdit_SetParaTabStops, _GUICtrlRichEdit_SetSpaceUnit

Voir aussi

Consultez EM_SETTABSTOPS dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    Local $idLblMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraphe 1" & @TAB & "Paragraphe 2" & @TAB & "Paragraphe 3")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetTabStops($hRichEdit, 1)
                    GUICtrlSetData($idLblMsg, "1. Définit les taquets à chaque pouce")
                Case 2
                    _GUICtrlRichEdit_SetTabStops($hRichEdit, "0.5;1.5")
                    GUICtrlSetData($idLblMsg, "2. Définit les taquets à 0.5 et 1.5 inches")

                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres dans Word
                    _GUICtrlRichEdit_Deselect($hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example