UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetReadOnly

Définit ou supprime l'état de lecture seule

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetReadOnly ( $hWnd [, $bState = True] )

Paramètres

$hWnd Handle du contrôle
$bState [optionnel] Une des valeurs suivantes:
    True - Définit le contrôle à lecture seule (par défaut)
    False - Définit le contrôle à lecture-écriture

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $bState n'est ni True ni False
700 - l'opération a échoué

Voir aussi

Consultez EM_SETREADONLY dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $hRichEdit, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    For $i = 1 To 5
        _GUICtrlRichEdit_AppendText($hRichEdit, "Ligne " & $i & @CRLF)
    Next
    _GUICtrlRichEdit_AppendText($hRichEdit, "Ligne 6")
    Report("Initial state")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetReadOnly($hRichEdit)
                    Report("Définit à lecture-seule")
                Case 2
                    _GUICtrlRichEdit_SetReadOnly($hRichEdit, False)
                    Report("Maintenant à lecture-écriture")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
     ;GUIDelete()   ; est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg & @CRLF & "Essayez de taper du texte")
EndFunc   ;==>Report