UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetRECT

Définit le rectangle d'édition d'un contrôle RichEdit

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetRECT ( $hWnd [, $iLeft = Default [, $iTop = Default [, $iRight = Default [, $iBottom = Default [, $bRedraw = True]]]]] )

Paramètres

$hWnd Handle du contrôle
$iLeft [optionnel] Position gauche en unités de dialogue
$iTop [optionnel] Position supérieure en unités de dialogue
$iRight [optionnel] Position droite en unités de dialogue
$iBottom [optionnel] Position inférieure en unités de dialogue
$bRedraw [optionnel] True pour forcer le rafraîchissement

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
1021 - $iLeft n'est pas un nombre positif
1022 - $iTop n'est pas un nombre positif
1023 - $iRight n'est pas un nombre positif
1024 - $iBottom n'est pas un nombre positif
1025 - $iLeft >= $iRight
1026 - $iTop >= $iBottom

Remarque

Le rectangle de mise en forme est le domaine dans lequel le texte est rédigé, dont une partie peut ne pas être visible.
Paramètres par défaut = aucun changement aux valeurs précédentes.
Si seulement $hWnd est défini, le domaine est initialisé comme à la création.

En relation

_GUICtrlRichEdit_GetRECT

Voir aussi

Consultez EM_SETMODIFY dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    Report("1. Paramètres par défaut ")
                Case 2
                    _GUICtrlRichEdit_SetRECT($g_hRichEdit, 10, 10, 100, 100)
                    Report("2. Paramètres ")
                Case 3
                    _GUICtrlRichEdit_SetRECT($g_hRichEdit)
                    Report("3. Retour aux paramètres par défaut")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    Local $aRect = _GUICtrlRichEdit_GetRECT($g_hRichEdit)
    $sMsg = $sMsg & @CRLF & @CRLF & "Gauche=" & $aRect[0] & " Haut=" & $aRect[1] & " Droite=" & $aRect[2] & " Bas=" & $aRect[3]
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report