Fonction _GUICtrlRichEdit

Définit la bordure des paragraphe(s) de la sélection courante ou, à défaut de sélection, des paragraphes insérés au point d'insertion

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaBorder ( $hWnd [, $sLocation = Default [, $vLineStyle = Default [, $sColor = Default [, $iSpace = Default]]]] )

Paramètres

Valeur de retour

Remarques

Pour définir des "unités d'espace" appelez _GUICtrlRichEdit_SetSpaceUnit(). Initialement le pouce.

Si du texte est sélectionné, les valeurs par défaut sont les valeurs du premier aragraphe du texte sélectionné.
A défaut de sélection, les valeurs par défaut sont les valeurs du paragraphe courant.

Pour supprimer une bordure, appelez la fonction avec les deux paramètres: ($hwnd, "").

Les bordures ne sont pas montrées dans RichEdit, mais celles qui sont créées ici seront visibles dans Word.

En relation

Voir aussi

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $iStep = 0, $idBtnNext
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($g_hRichEdit, "Premier paragraphe")
    Report("0. Premier paragraphe: paramètres par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaBorder($g_hRichEdit, "o", 3, "mag", 0.25)
                    Report("1. Second paragraphe: with border (should show in Word)")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, -1)
                    Report("2. Settings of Premier paragraphe in selection")
                Case 3
                    _GUICtrlRichEdit_SetParaBorder($g_hRichEdit, "l", 6, "blu")
                    Report("3. Settings of both paragraphs changed")
                Case 4
                    _GUICtrlRichEdit_SetParaBorder($g_hRichEdit, Default, ".75gd")
                    Report("4. Line style changed")
                Case 5
                    ; Sauve tout le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres de bordure dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd
 
    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & @CRLF & _GUICtrlRichEdit_GetParaBorder($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report

Succès:	Retourne True.
Échec:	Retourne False et définit @error <> 0.
@error:	101 - $hWnd n'est pas un handle 102 - valeur de $sLocation invalide 103 - valeur de $iLineStyle invalide 104 - valeur de $sColor invalide 105 - $iSpace n'est ni un nombre positif ni zéro

$hWnd	Handle du contrôle
$sLocation	[optionnel] une chaîne constituée d'une combinaison logique de : "l" - bordure gauche "r" - bordure droite "t" - bordure supérieure "b" - bordure inférieure "i" - bordure intérieure "o" - bordure extérieure ou "" (vide) - pas de bordure
$vLineStyle	[optionnel] Style de ligne - une des valeurs suivantes: "none" - pas de ligne .75 - 3/4 de point 1.5 - 1 point 1/2 2.25 - 2 points 1/4 3 - 3 points 4.5 - 4 points 1/2 6 - 6 points ".75d" - 1/2 point, double "1.5d" - 1 point 1/2, double "2.25d" - 2 points 1/4 , double ".75g" - 3/4 point gris ".75gd" - 3/4 point gris en pointillé
$sColor	[optionnel] Un des valeurs suivantes: "aut" - AutocolorMC "blk" - noir "blu" - bleu "cyn" - cyan "grn" - vert "mag" - magenta "red" - rouge "yel" - jaune "whi" - blanc "dbl" - bleu foncé "dgn" - vert foncé "dmg" - magenta foncé "drd" - rouge foncé "dyl" - jaune foncé "dgy" - gris foncé "lgy" - gris clair
$iSpace	[optionnel] Espace entre la bordure et le texte (en unités d'espace) ( valeur initiale: 0)