UDF > GUI > GuiRichEdit >


_GUICtrlRichEdit_SetParaAttributes

Définit les attributs des paragraphe(s) dans la sélection courante ou, à défaut de sélection, des paragraphes insérés au point d'insertion

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaAttributes ( $hWnd, $sStatesAndAtts )

Paramètres

$hWnd Handle du contrôle
$sStatesAndAtts Une chaîne constituée de groupes séparés par des points-virgules ";".
Chaque groupe se compose de:
Caractère 1 - Etat:
    "+" - L'attribut est On
    "-" - L'attribut est Off
Caractères 2 à 4 - Attribut:
    "fpg" - force ces paragraphe(s) sur de nouvelles pages (Initialement Off)
    "hyp" - applique la césure automatique (initialement On)
    "kpt" - garde ces paragraphe(s) ensemble sur une page ( Initialement Off}
    "kpn" - garde ce/ces paragraphes et le suivant, ensemble sur une page (Initialement Off)
    "pwo" - évite les veuves et les orphelines, à savoir, évite une seule ligne de ces paragraphe(s) sur une page (Initialement Off)
    "r2l" - affiche un texte en utilisant l'ordre de lecture de droite à gauche (Initialement Off)
    "row" - les paragraphe(s) sont les lignes d'un tableau (Initialement Off)
    "sbs" - affiche les paragraphe(s) côte à côte (Initialement Off)
    "sln" - supprime les numéros de ligne dans le document ou les sections avec des numéros de ligne (Initialement Off)

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
1021 - le caractère d'état dans $sStatesAndAtts est invalide. Il est dans @extended
1022 - une abréviation de l'attribut dans $sStatesAndAtts est invalide. Il est dans @extended
1023 - la longueur de $sStatesAndAtts est invalide

Remarque

Affiche les résultats dans Word mais pas dans RichEdit.

En relation

_GUICtrlRichEdit_GetParaAttributes

Voir aussi

Consultez EM_SETPARAFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($g_hRichEdit, "Premier paragraphe")
    Report("Premier paragraphe: attributs par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaAttributes($g_hRichEdit, "-hyp")
                    Report("Second paragraphe: hyphenation off")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, -1)
                    _GUICtrlRichEdit_SetParaAttributes($g_hRichEdit, "-hyp; + FPG; + kpn")
                    Report("Attributs du premier paragraphe de la sélection")
                Case 3
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissez regarder les attributs dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & @CRLF & _GUICtrlRichEdit_GetParaAttributes($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report