UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetModified

Définit l'indicateur de modification

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetModified ( $hWnd [, $bState = True] )

Paramètres

$hWnd Handle du contrôle
$bState [optionnel] Spécifie la nouvelle valeur de l'indicateur de modification :
True - Indique que le texte a été modifié (par défaut)
False - Indique qu'il n'a pas été modifié.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $bState doit être True ou False

Remarque

Le système définit automatiquement l'indicateur de modification à False lorsque le contrôle est créé.
Si le texte du contrôle est modifié, par l'utilisateur ou par programme, le système définit l'indicateur à True.
Appelez _GUICtrlRichEdit_IsModified() pour obtenir l'état de l'indicateur.

En relation

_GUICtrlRichEdit_IsModified

Voir aussi

Consultez EM_SETMODIFY dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

        Report("État initial après création")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Un paragraphe")
                    Report("Du texte a été ajouté")
                Case 2
                    _GUICtrlRichEdit_SetModified($g_hRichEdit, False)
                    Report("Après effacement du flag de modification")
                Case 3
                    GUICtrlSetData($g_idLblMsg, "Tapez du texte puis cliquez sur Next")
                Case 4
                    Report("Après la saisie")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & "State is " & _GUICtrlRichEdit_IsModified($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report