UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetParaTabStops

Obtient les taquets de tabulation du premier paragraphe sélectionné ou, à défaut de sélection, du paragraphe courant

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaTabStops ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne une chaîne composée de valeurs séparées par des points-virgules.
    Valeur 1 - Nombre de taquets
    Valeurs 2 à [valeur 1] + 1 - Description des taquets:
    position absolue d'un taquet de tabulation (en unités d'espace)
    sorte de taquet
        l - taquet à gauche - l
        c - taquet au centre
        r - taquet décimal
        b - taquet barre (une barre verticale, comme dans Word)
    sorte de point de suite (leader point)
        . - en pointillés
        - - en tirets
        _ - caractère de soulignement
        = - double ligne
        t - ligne fine
        un espace - pas de leader
    Valeur [value 1] + 2 - Portée:
        a - tous (ou seulement)les paragraphes sélectionnés ont ces paramètres
        f - le premier paragraphe sélectionné a ces paramètres, mais d'autres ne l'ont pas
        c - le paragraphe courant a ces paramètres
Échec: Retourne "" et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

Remarque

Pour entrer une tabuklation dans un contrôle, appuyez sur Ctrl_Tab.

En relation

_GUICtrlRichEdit_SetParaTabStops

Voir aussi

Consultez EM_GETPARAFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    Report("0. Paragraphe avec les paramètres par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaTabStops($g_hRichEdit, ".3l ;1c ;2.5r.").
                    Report("1. Taquet du second paragraphe")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                    Report("2. Taquet du premier paragraphe")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    Report("Taquet du premier paragraphe de la sélection")
                Case 4
                    _GUICtrlRichEdit_SetParaTabStops($g_hRichEdit, "2.3r=")
                    Report("3. Change les taquets des deux paragraphes à la fois")
                Case 5
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete (); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & @CRLF & _GUICtrlRichEdit_GetParaTabStops($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report