UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetParaSpacing

Obtient les paramètres d'espacement du premier paragraphe sélectionné ou, à défaut de sélection, du paragraphe courant

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaSpacing ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne une chaîne composée de paramètres séparés par des points-virgules :
    Valeur 1 - Espacement interligne :
        soit un nombre - en unités d'espace
        soit "(nombre) lines" - en lignes
    Valeur 2 - Portée de la valeur 1 :
        a - tous (ou seulement) les paragraphes sélectionnés ont les paramètres ci-dessus
        f - le premier paragraphe sélectionné a ce paramètre, mais d'autres ne l'ont pas
        c - le paragraphe courant a ce paramètre
    Valeur 3 - Espacement avant les paragraphes (en unités d'espce)
    Valeur 4 - Portée de la valeur 3 - voir ci-dessus
    Valeur 5 - Espacement après les paragraphes (en unités d'espace)
    Valeur 6 - Portée de la valeur 5 - voir ci-dessus
Échec: Retourne "" et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

En relation

_GUICtrlRichEdit_SetParaSpacing

Voir aussi

Consultez EM_SETPARAFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    Report("0. Paragraphe avec les paramètres par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    _GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, "2 lines", .2, .25)
                    Report("1. L'espacement du second paragraphe est ")
                Case 2
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                    Report("2. Les paramètres du premier paragraphe de la sélection sont ")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, Default, .1)
                    Report("3. Change l'espacement des deux paragraphes à la fois")
                Case 4
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres de retraits dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction " & @CRLF & _GUICtrlRichEdit_GetParaSpacing($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report