UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetParaIndents

Obtient les paramètres de retrait de la bordure du (premier) paragraphe sélectionné ou (à défaut de sélection) du paragraphe courant

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaIndents ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne les paramètres - une chaîne constituée de valeurs séparées par des points-virgules:
    Valeur 1 - Left - indentation du côté gauche du corps du paragraphe (des lignes après la première) (en unités d'espace)
    Valeur 2 - Right - indentation du côté droit du paragraphe (en unités d'espace)
    Valeur 3 - FirstLine - indentation de la première ligne par rapport aux autres lignes (en unités d'espace)
    Valeur 4 - portée :
        a - tous (ou seulement) les paragraphes sélectionnés ont ces paramètres
        f - le premier paragraphe sélectionné a ces paramètres, mais d'autres(s) ne l'ont pas
        c - le paragraphe courant a ces paramètres
Échec: Retourne "" et définit @error <> 0..
@error: 101 - $hWnd n'est pas un handle

Remarque

Des valeurs postives de $iLeft, $$iRight et iFirstLine indentent vers le centre du paragraphe.

En relation

_GUICtrlRichEdit_SetParaIndents

Voir aussi

Consultez EM_GETPARAFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    Report("Paragraphe avec les paramètres de retrait par défaut")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphe")
                    Report("A ajouté un second paragraphe")
                Case 2
                    _GUICtrlRichEdit_SetParaIndents($g_hRichEdit, 0.25, .1)
                    Report("A changé les paramètres de retrait du second paragraphe")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                    _GUICtrlRichEdit_SetParaIndents($g_hRichEdit, Default, 0, .2)
                    Report("Change les paramètres des paragraphes")
                Case 4
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres de retrait dans Word
                    _GUICtrlRichEdit_Deselect($g_hRichEdit)
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi            
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & @CRLF & _GUICtrlRichEdit_GetParaIndents($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report