UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetFont

Obtient les attributs de police d'une sélection ou, à défaut de sélection, au point d'insertion

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetFont ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne un tableau contenant les valeurs:
[0] - taille d'un point
    0 si les tailles sont différentes dans la sélection
[1] - le nom de la police
    "" Si les polices sont différentes dans la sélection
[2] - le jeu de caractères
    $ANSI_CHARSET - 0
    $BALTIC_CHARSET - 186
    $CHINESEBIG5_CHARSET - 136
    $EASTEUROPE_CHARSET - 238
    $GB2312_CHARSET - 134
    $GREEK_CHARSET - 161
    $HANGEUL_CHARSET - 129
    $HEBREW_CHARSET - 177
    $JOHAB_CHARSET - 130
    $MAC_CHARSET - 77
    $OEM_CHARSET - 255
    $RUSSIAN_CHARSET - 204
    $SHIFTJIS_CHARSET - 128
    $SYMBOL_CHARSET - 2
    $THAI_CHARSET - 222
    $TURKISH_CHARSET - 162
    $VIETNAMESE_CHARSET - 163
Ces constantes se trouvent dans FontConstants.au3.
Échec: Définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

En relation

_GUICtrlRichEdit_SetFont

Voir aussi

Consultez EM_GETCHARFORMAT in MSDN Library. Search LOGFONT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    Report("1. Initial")
                Case 2
                    _GUICtrlRichEdit_SetFont($g_hRichEdit, 15, "Times New Roman")
                    Report("2. Définit Police")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
   
EndFunc   ;==>Example

Func Report($sMsg)
    Local $aRet = _GUICtrlRichEdit_GetFont($g_hRichEdit)
    $sMsg = $sMsg & @CRLF & @CRLF & $aRet[1] & " " & $aRet[0] & " points"
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report