UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetBkColor

Obtient la couleur de fond du contrôle

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetBkColor ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne une valeur COLORREF.
Échec: Définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

Remarque

Si vous avez besoin de créer un tableau de couleur, utilisez _ColorGetCOLORREF(), pas _ColorGetRGB().

En relation

_GUICtrlRichEdit_SetBkColor

Voir aussi

Consultez EM_SETBKGNDCOLOR dans la librairie MSDN.

Exemple

#include <Color.au3>
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Paragraphe 1")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit, 0xE8CCCC)
                        Report("1. A coloré le fond")
                    Case 2
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit)
                        Report("2. Noir en blanc")
                    Case 3
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit, 0xB3B3C7)
                        Report("3. A coloré le fond de nouveau")
                        ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les paramètres dans Word
                        _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    Local $iBngColor = _GUICtrlRichEdit_GetBkColor($g_hRichEdit)
    Local $aRet = _ColorGetRGB($iBngColor)
    $sMsg = $sMsg & @CRLF & @CRLF & $aRet[0] & ";" & $Aret[1] & ";" & $Aret[2] & " BngColor=0x" & Hex($iBngColor)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report