UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_FindText

Recherche un texte qui démarre au point d'insertion ou au point d'ancrage de la sélection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_FindText ( $hWnd, $sText [, $bForward = True [, $bMatchCase = False [, $bWholeWord = False [, $iBehavior = 0]]]] )

Paramètres

$hWnd Handle du contrôle
$sText Texte à rechercher
$bForward [optionnel] Sens de la recherche
(Win 95: la recherche est toujours en avant)
$bMatchCase [optionnel] Recherche sensible à la casse
Default: casse insensible
$bWholeWord [optionnel] Recherche seulement un mot entier
Default: mot partiel ou total
$iBehavior [optionnel] Toute combinaison de BITOR de $FR_MATCHALEFHAMZA, $FR_MATCHDIAC et $FR_MATCHKASHIDA
Default: 0

Valeur de retour

Succès: Retourne la position inter-caractères avant le début de la reconnaissance de texte s'il est trouvé, sinon -1.
Échec: Définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $sText = ""
103 - $bForward n'est ni True ni False
104 - $bMatchCase n'est ni True ni False
105 - $bWholeWord n'est ni True ni False
1061 - $IBehavior n'est pas un nombre
1062 - $IBehavior est invalide

En relation

_GUICtrlRichEdit_FindTextInRange

Voir aussi

Consultez EM_FINDTEXT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext,$hRichEdit, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Ceci est du texte ajouté.")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetSel($hRichEdit, 8, 8)
                    Report("1.Définit la position de départ ")
                Case 2
                    Report('2."ajouté" trouvé juste après la position inter-character '& _
                            _GUICtrlRichEdit_FindText($hRichEdit, "ajouté"))
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    GUIDelete()

EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report