UDF > GUI > GuiListView >

_GUICtrlListView_SetIconSpacing

Définit l'espacement entre les icônes lorsque le style est grandes icônes

#include <GuiListView.au3>
_GUICtrlListView_SetIconSpacing ( $hWnd, $iCX, $iCY )

Paramètres

$hWnd ID/handle du contrôle
$iCX Distance horizontale, en pixels, entre les icônes
$iCY Distance verticale, en pixels, entre les icônes

Valeur de retour

Retourne un tableau avec le format suivant :
    [0] - Valeur précédente de $iCX
    [1] - Valeur précédente de $iCY

Remarque

Les valeurs de $iCX et $iCY sont relatives au coin supérieur gauche du bitmap de l'icône. Pour définir l'espacement entre les icônes pour qu'elles ne se chevauchent pas, les valeurs $iCX ou $iCY doivent inclure la taille de l'icône, et en plus la valeur de l'espace vide souhaitée entre les icônes.
Des valeurs inférieures à la largeur de l'icône entraîneront des chevauchements.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hImage, $idListview

    ; Crée une GUI
    GUICreate("ListView Set Icon Spacing", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($idListview, $LVS_ICON)
    GUISetState(@SW_SHOW)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 0)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
    _GUICtrlListView_AddItem($idListview, "Item 2", 1)
    _GUICtrlListView_AddItem($idListview, "Item 3", 2)

    ; Modifie l'espacement des éléments
    MsgBox($MB_SYSTEMMODAL, "Information", "Changing icon spacing")
    _GUICtrlListView_SetIconSpacing($idListview, 32, 32)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example