UDF > GUI > GuiListView >

_GUICtrlListView_FindParam

Recherche un élément avec le lParam spécifiée

#include <GuiListView.au3>
_GUICtrlListView_FindParam ( $hWnd, $iParam [, $iStart = -1] )

Paramètres

$hWnd ID/handle du contrôle
$iParam Valeur Param à rechercher
$iStart [optionnel] Index de l'élément, de base 0, à partir duquel lancer la recherche ou -1 pour commencer depuis le début.
L'élément spécifié est lui-même exclu de la recherche.

Valeur de retour

Succès: Retourne l'index de l'élément, de base 0.
Échec: Retourne -1.

En relation

_GUICtrlListView_FindItem

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

; Attention n'utilisez pas SetItemParam avec des éléments créés avec GUICtrlCreateListViewItem
; Param est le controlID de l'élément

Example()

Func Example()
    Local $hGUI, $iI, $hListView

    ; Crée une GUI
    $hGUI = GUICreate("(UDF Created) ListView Find Param", 400, 300)
    $hListView = _GUICtrlListView_Create($hGUI, "", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 100
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Définit la valeur Param du 50-ième élément
    _GUICtrlListView_SetItemParam($hListView, 49, 1234)

    ; Cherche l'élément
    $iI = _GUICtrlListView_FindParam($hListView, 1234)
    MsgBox($MB_SYSTEMMODAL, "Information", "Target Item Index: " & $iI)
    _GUICtrlListView_EnsureVisible($hListView, $iI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example