UDF > GUI > GuiListView >

_GUICtrlListView_FindItem

Recherche un élément avec les caractéristiques spécifiées

#include <GuiListView.au3>
_GUICtrlListView_FindItem ( $hWnd, $iStart, ByRef $tFindInfo [, $sText = ""] )

Paramètres

$hWnd ID/handle du contrôle
$iStart Index de l'élément, de base 0, à partir duquel lancer la recherche ou -1 pour recommencer depuis le début.
L'élément spécifié est lui-même exclu de la recherche.
$tFindInfo Structure $tagLVFINDINFO qui contient les informations de recherche.
$sText [optionnel] Chaîne à comparer avec le texte de l'élément.
Il faut que $LVFI_STRING ou $LVFI_PARTIAL soit défini dans le membre Flags.

Valeur de retour

Succès: Retourne l'index de l'élément, de base 0.
Échec: Retourne -1.

En relation

$tagLVFINDINFO, _GUICtrlListView_FindNearest, _GUICtrlListView_FindParam

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $tInfo, $iI, $idListview

    GUICreate("ListView Find Item", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 100
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Définit la valeur du paramètre du 50-ième élément
    _GUICtrlListView_SetItemParam($idListview, 49, 1234)

    ; Cherche l'élément
    $tInfo = DllStructCreate($tagLVFINDINFO)
    DllStructSetData($tInfo, "Flags", $LVFI_PARAM)
    DllStructSetData($tInfo, "Param", 1234)
    $iI = _GUICtrlListView_FindItem($idListview, -1, $tInfo)
    MsgBox($MB_SYSTEMMODAL, "Information", "Target Item Index: " & $iI)
    _GUICtrlListView_EnsureVisible($idListview, $iI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example