UDF > GUI > GuiListView >

_GUICtrlListView_SetItemParam

Définit la valeur spécifique d'un élément

#include <GuiListView.au3>
_GUICtrlListView_SetItemParam ( $hWnd, $iIndex, $iParam )

Paramètres

$hWnd Handle du contrôle
$iIndex Index de l'élément, de base 0
$iParam Une valeur à associer à l'élément

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Comme AutoIt utilise le paramètre $iParam pour stocker le controlID des éléments de la ListView créés de façon native, cette valeur doit être suffisamment élevé pour les éléments créés avec l'UDF, afin d'éviter tout conflit avec des contrôles existants - une valeur de départ de 1000 est recommandé.

En relation

_GUICtrlListView_GetItemParam

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Set Item Param", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")
    _GUICtrlListView_AddItem($idListview, "Item 3")

    ; Définit le paramètre de l'élément 2
    _GUICtrlListView_SetItemParam($idListview, 1, 1234)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 2 Parameter: " & _GUICtrlListView_GetItemParam($idListview, 1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example