UDF > GUI > GuiEdit >

_GUICtrlEdit_ReplaceSel

Remplace la sélection actuelle

#include <GuiEdit.au3>
_GUICtrlEdit_ReplaceSel ( $hWnd, $sText [, $bUndo = True] )

Paramètres

$hWnd ID/handle du contrôle
$sText Chaîne contenant le texte de remplacement.
$bUndo [optionnel] Spécifie si l'opération de remplacement peut être annulée:
    True - L'opération peut être annulée.
    False - L'opération ne peut être annulée.

Valeur de retour

Aucune.

Remarque

Utilisez _GUICtrlEdit_ReplaceSel() pour remplacer seulement une partie du texte dans le contrôle d'édition.
S'il n'y a pas de sélection en cours, le texte de remplacement est inséré à la position actuelle du curseur.

En relation

_GUICtrlEdit_GetSel, _GUICtrlEdit_SetSel

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[3] = [200, 378, -1]

    ; Crée une GUI
    $hGUI = GUICreate("Edit Replace Sel", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 2, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Définit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Définit le texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))

    ; Définit la sélection
    _GUICtrlEdit_SetSel($idEdit, 0, 8)

    MsgBox($MB_SYSTEMMODAL, "Information", "Replace Sel")
    _GUICtrlEdit_ReplaceSel($idEdit, StringFormat("%d/%2d/%4d", @MON, @MDAY, @YEAR))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example