UDF > GUI > GuiEdit >

_GUICtrlEdit_LineFromChar

Obtient le numéro de la ligne qui contient l'index spécifié d'un caractère

#include <GuiEdit.au3>
_GUICtrlEdit_LineFromChar ( $hWnd [, $iIndex = -1] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex [optionnel] L'index du caractère contenu dans la ligne dont le numéro doit être récupéré

Valeur de retour

Retourne le numéro de la ligne contenant l'index de caractère, spécifié par $iIndex, à partir de 0.

Remarque

Si $iIndex est -1, _GUICtrlEdit_LineFromChar() récupère soit le numéro de la ligne courante (la ligne contenant le curseur), soit, s'il existe une sélection, le numéro de la ligne contenant le début de la sélection.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI, $iRandom
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

    ; Crée une GUI
    $hGUI = GUICreate("Edit Line From Char", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Définit le texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))

    ; Ligne du caractère
    $iRandom = Random(0, _GUICtrlEdit_GetTextLen($idEdit) - 1, 1)
    _GUICtrlEdit_SetSel($idEdit, $iRandom - 1, $iRandom)
    _GUICtrlStatusBar_SetText($hStatusBar, "Character  " & $iRandom & " is in a line: " & _GUICtrlEdit_LineFromChar($idEdit, $iRandom))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example