UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_GetItem

Récupère les attributs d'un élément

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItem ( $hWnd, $iIndex )

Paramètres

$hWnd Handle du contrôle
$iIndex 0 Index, compté à partir de 0, de l'élément

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Texte de l'élément
    [1] - Longueur du texte de l'élément
    [2] - Nombre de largeurs d'image de retrait de l'élément
    [3] - Index, compté à partir de 0, de l'image de l'élément
    [4] - Index, compté à partir de 0, de l'image d'état de l'élément
    [5] - Index, compté à partir de 0, de recouvrement de l'image de l'élément
    [6] - Item application defined value

En relation

_GUICtrlComboBoxEx_GetItemEx, _GUICtrlComboBoxEx_SetItem

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hImage, $aItem, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Get Item", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ; Définit le retrait de l'élément
    _GUICtrlComboBoxEx_SetItemIndent($hCombo, 1, 1)

    $aItem = _GUICtrlComboBoxEx_GetItem($hCombo, 1)
    MemoWrite("Item Text : " & $aItem[0])
    MemoWrite("Item Len ..........................: " & $aItem[1])
    MemoWrite("# image widths to indent ..........: " & $aItem[2])
    MemoWrite("0-based item image index .......: " & $aItem[3])
    MemoWrite("0-based item state image index .: " & $aItem[4])
    MemoWrite("0-based item image overlay index: " & $aItem[5])
    MemoWrite("Item application defined value ....: " & $aItem[6])

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite