UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetItem

Définit une partie ou tous les attributs d'un élément

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetItem ( $hWnd, $sText [, $iIndex = 0 [, $iImage = -1 [, $iSelectedImage = -1 [, $iOverlayImage = -1 [, $iIndent = -1 [, $iParam = -1]]]]]] )

Paramètres

$hWnd Handle du contrôle
$sText Texte de l'élément. Voir Remarque.
$iIndex [optionnel] Index, compté à partir de 0, de l'élément
$iImage [optionnel] Index, compté à partir de 0, de l'icône de l'élément de la liste d'images du contrôle
$iSelectedImage [optionnel] Index, compté à partir de 0, de l'icône de l'élément de la liste d'images du contrôle
$iOverlayImage [optionnel] Index, compté à partir de 0, de l'icône de l'élément de la liste d'images du contrôle
$iIndent [optionnel] Nombre de largeurs d'image du retrait de l'élément. Une seule empreinte est égale à la largeur d'une image.
$iParam [optionnel] Valeur spécifique à l'élément

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Si un rappel de notification est nécessaire, vous devez spécifier $sText = -1 (LPSTR_TEXTCALLBACK).

En relation

_GUICtrlComboBoxEx_GetItem, _GUICtrlComboBoxEx_SetItemEx

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $iImage, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Set Item", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    For $x = 0 To 149
        $iImage = Random(0, 8, 1)
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $iImage, $iImage)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    ; Modifie l'élément 2
    MsgBox($MB_SYSTEMMODAL, "Information", "Changing item 2")
    _GUICtrlComboBoxEx_SetItem($hCombo, "New Item 2", 1)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example