UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_AddString

Ajoute une chaîne

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_AddString ( $hWnd, $sText [, $iImage = -1 [, $iSelectedImage = -1 [, $iOverlayImage = -1 [, $iIndent = -1 [, $iParam = -1]]]]] )

Paramètres

$hWnd Handle du contrôle
$sText Texte de l'élément. S'il est défini à -1, l'élément est défini par l'intermédiaire du message de notification $CBEN_GETDISPINFO.
$iImage [optionnel] Index, compté à partir de 0, de l'icône d'élément dans la liste d'images du contrôle
$iSelectedImage [optionnel] Index, compté à partir de 0, de l'icône d'élément dans la liste d'images du contrôle
$iOverlayImage [optionnel] Index, compté à partir de 0, de l'icône d'élément dans la liste d'images du contrôle
$iIndent [optionnel] Nombre de largeurs d'image pour le retrait de l'élément. Une seule indentation est égale à la largeur d'une image.
$iParam [optionnel] Valeur spécifique de l'élément

Valeur de retour

Succès: Retourne l'index du nouvel élément.
Échec: Retourne -1.

En relation

_GUICtrlComboBoxEx_DeleteString, _GUICtrlComboBoxEx_InitStorage

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Add String", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    For $x = 0 To 146
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", $x)
    Next
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)

    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    For $x = 0 To 149
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 200, 1)), $x, $x)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example