Fonction _FTP_ProgressUpload

Télécharge vers le serveur un fichier en mode binaire en affichant une barre de progression ou en appelant une fonction définie par l'utilisateur

#include <FTPEx.au3>
_FTP_ProgressUpload ( $hFTPSession, $sLocalFile, $sRemoteFile [, $hFunctionToCall = 0] )

Paramètres

Valeur de retour

Remarque

Informations sur $hFunctionToCall:
    Paramètre: $iPercentage - Le pourcentage de la progression
    Valeurs de retour :
        Continue Uplpad - 1
        Abandonner Upload - zéro ou négatif par exemple 0 ou -1
    Ces valeurs sont retournées par _FTP_ProgressUpload(), de sorte que vous pouvez réagir sur différentes actions comme l'Abandon par l'utilisateur, la fermeture de l'App ou le TimeOut du processus.

Exemples

Exemple 1

#include <FTPEx.au3>
#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <ProgressConstants.au3>

; Cet exemple DOIT être adapté pour valider $g_sRemoteFile/$s$erver/$sUsername/$sPass

Global $g_sRemoteFile = "/pub/software/databases/rt/SRPMS/ucs-local-modperl-2.0.3-1.src.rpm"
Global $g_sLocalFile = @TempDir & "\temp.tmp"

Local $sServer = 'ftp.csx.cam.ac.uk'
Local $sUsername = ''
Local $sPass = ''

Local $hInternetSession = _FTP_Open('MyFTP Control')
; Passive permet plus de protection FTPs pour répondre
Local $hFTPSession = _FTP_Connect($hInternetSession, $sServer, $sUsername, $sPass, 1)

Example()

_FTP_Close($hInternetSession)

Func Example()
    Local $sFunctionToCall = "_UpdateProgress"
    ProgressOn("Upload Progress", $g_sRemoteFile)
    _FTP_ProgressUpload($hFTPSession, $g_sLocalFile, $g_sRemoteFile, $sFunctionToCall)
    ProgressOff()
EndFunc   ;==>Example

Func _UpdateProgress($iPercent)
    ProgressSet($iPercent, $iPercent & "%")
    If _IsPressed("77") Then Return 0 ; Abandon avec F8
    Return 1 ; Continue le téléchargement vers le serveur
EndFunc   ;==>_UpdateProgress

Exemple 2

#include <FTPEx.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

; Cet exemple DOIT être adapté pour valider $g_sRemoteFile/$s$erver/$sUsername/$sPass

Global $g_sRemoteFile = "/pub/software/databases/rt/SRPMS/ucs-local-modperl-2.0.3-1.src.rpm"
Global $g_sLocalFile = @TempDir & "\temp.tmp"

Local $sServer = 'ftp.csx.cam.ac.uk'
Local $sUsername = ''
Local $sPass = ''

Local $hInternetSession = _FTP_Open('MyFTP Control')
; Passive permet plus de protection FTPs pour répondre
Local $hFTPSession = _FTP_Connect($hInternetSession, $sServer, $sUsername, $sPass, 1)

Global $g_idProgressBarCtrl, $g_idBtn_Cancel

Example()

_FTP_Close($hInternetSession)

Func Example()
    ; Crée une GUI
    GUICreate("My GUI upload Progressbar", 220, 100, 100, 200)
    GUICtrlCreateLabel($g_sRemoteFile, 10, 10)
    $g_idProgressBarCtrl = GUICtrlCreateProgress(10, 40, 200, 20, $PBS_SMOOTH)
    GUICtrlSetColor(-1, 32250); Ne fonctionne pas avec les styles Windows XP
    $g_idBtn_Cancel = GUICtrlCreateButton("Cancel", 75, 70, 70, 20)
    GUISetState(@SW_SHOW)

    Local $sFunctionToCall = "_UpdateGUIProgressBar"
    _FTP_ProgressUpload($hFTPSession, $g_sLocalFile, $g_sRemoteFile, $sFunctionToCall)
    Exit @error
EndFunc   ;==>Example

Func _UpdateGUIProgressBar($iPercent)
    GUICtrlSetData($g_idProgressBarCtrl, $iPercent)
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Return -1 ; _FTP_UploadProgress Annule avec -1, de sorte que vous pouvez quitter votre application après
        Case $g_idBtn_Cancel
            Return -2 ; Juste Annuler, sans valeur de retour spéciale
    EndSwitch
    Return 1 ; Sinon continuer le téléchargement
EndFunc   ;==>_UpdateGUIProgressBar

Succès:	Retourne 1.
Échec:	Retourne 0 et définit @error <> 0.
@error:	-1 - Le fichier local n'a pas pu être ouvert -3 - La création du fichier a échoué -4 - L'écriture du fichier a échoué -5 - La fermeture du fichier a échoué -6 - Upload interrompu par PercentageFunc et retourne à la fonction appelée

$hFTPSession	Handle retourné par _FTP_Connect().
$sLocalFile	Le fichier local source.
$sRemoteFile	Le fichier distant à créer.
$hFunctionToCall	[optionnel] Une variable affectée par la fonction définie par l'utilisateur pour mettre à jour une barre de progression ou réagir à une interaction de l'utilisateur, comme l'interruption ou à la sortie du processus. Par défaut = Aucun. Voir Remarques.