Functions > MessageBoxesDialogs >

ProgressOn

Crée une fenêtre contenant une barre de progression personnalisée.

ProgressOn ( "title", "maintext" [, "subtext" [, x pos [, y pos [, opt]]]] )

Paramètres

title	Titre de la fenêtre de progression.
maintext	Texte de l'étiquette principale, en gras, au dessus de la barre.
subtext	[optionnel] Texte de l'étiquette secondaire, graisse normale, en dessous. (Par défaut, vide)
x pos	[optionnel] Coordonnée X du coin supérieur gauche (en pixels) de la fenêtre de progression (par défaut elle est centrée).
y pos	[optionnel] Coordonnée Y du coin supérieur gauche (en pixels) de la fenêtre de progression (par défaut elle est centrée)
opt	[optionnel] Par défaut elle est 'toujours OnTop/avec titre' Ajouter les options suivantes que vous voulez: $DLG_NOTITLE (1) = Fenêtre sans bordure et sans titre $DLG_NOTONTOP (2) = Sans l'attribut "toujours OnTop" $DLG_MOVEABLE (16) = Fenêtre déplaçable Les constantes sont définies dans AutoItConstants.au3

Valeur de retour

Aucune.

Remarque

Pour passer un paramètre optionnel, en laissant sa valeur par défaut inchangée, utilisez:
"" pour les paramètres chaîne
-1 pour les paramètres numériques
Si ProgressOn() est appelée alors qu'une fenêtre de progression existe déjà, la fenêtre est redessinée/déplacée. (Si vous voulez plusieurs fenêtres de progression simultanées, vous devez utiliser plusieurs scripts.)

En relation

ProgressOff, ProgressSet

Exemple

#include <AutoItConstants.au3>

Example()

Func Example()
    ; Affiche une fenêtre de barre de progression.
    ProgressOn("Progress Meter", "Incrémenté chaque seconde", "0%", -1, -1, BitOR($DLG_NOTONTOP, $DLG_MOVEABLE))

    ; Met à jour la valeur de la progression de la fenêtre de la barre de progression à chaque seconde.
    For $i = 10 To 100 Step 10
        Sleep(1000)
        ProgressSet($i, $i & "%")
    Next

    ; Définit le texte secondaire et le texte principal de la fenêtre de la barre de progression.
    ProgressSet(100, "Fait", "Terminé")
    Sleep(5000)

    ; Ferme la fenêtre de progression.
    ProgressOff()
EndFunc   ;==>Example